1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
|
;
; SIMD for interpolation
; Copyright 2019 Anton Khirnov <anton@khirnov.net>
;
; This program is free software: you can redistribute it and/or modify
; it under the terms of the GNU General Public License as published by
; the Free Software Foundation, either version 3 of the License, or
; (at your option) any later version.
;
; This program is distributed in the hope that it will be useful,
; but WITHOUT ANY WARRANTY; without even the implied warranty of
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
; GNU General Public License for more details.
;
; You should have received a copy of the GNU General Public License
; along with this program. If not, see <http://www.gnu.org/licenses/>.
;/
%include "config.asm"
%include "util.asm"
%include "x86inc.asm"
SECTION .text
; double
%define ELEM_SIZE 8
; transpose a 4x4 matrix of doubles, supplied in %1-%4
; %5, %6: temporary registers (clobbered)
%macro TRANSPOSE4x4 6
unpcklpd %5, %1, %2 ; %5 = 00 10 02 12
unpckhpd %6, %1, %2 ; %6 = 01 11 03 13
unpcklpd %1, %3, %4 ; %1 = 20 30 22 32
unpckhpd %4, %3, %4 ; %4 = 21 31 23 33
vperm2f128 %3, %5, %1, 00110001b ; %3 = 02 12 22 32
vinsertf128 %1, %5, xmm%1, 1 ; %1 = 00 10 20 30
vinsertf128 %2, %6, xmm%4, 1 ; %2 = 01 11 21 31
vperm2f128 %4, %6, %4, 00110001b ; %4 = 03 13 23 33
%endmacro
INIT_YMM avx2
cglobal transfer_interp_line_cont_4, 9, 11, 16, dst, dst_len, src, src_stride, idx_x, fact_x, fact_x_stride, fact_y, fact_y_stride,\
idx_x_val, fact_x3
shl fact_y_strideq, 3
shl fact_x_strideq, 3
shl src_strideq, 3
shl dst_lenq, 3
add dstq, dst_lenq
add idx_xq, dst_lenq
add fact_xq, dst_lenq
neg dst_lenq
; from now on, the register that held the line size is used as the offset into data arrays
%define offsetq dst_lenq
; load the y interpolation factors
SPLATPD m0, [fact_yq + fact_y_strideq * 0], 0 ; fact y + 0 -> m0
SPLATPD m1, [fact_yq + fact_y_strideq * 1], 0 ; fact y + 1 -> m1
SPLATPD m2, [fact_yq + fact_y_strideq * 2], 0 ; fact y + 2 -> m2
add fact_yq, fact_y_strideq
SPLATPD m3, [fact_yq + fact_y_strideq * 2], 0 ; fact y + 3 -> m3
; reuse the now unneded fact_y[_stride] registers
%define fact_x1q fact_yq
%define fact_x2q fact_y_strideq
lea fact_x1q, [fact_xq + fact_x_strideq]
lea fact_x2q, [fact_xq + fact_x_strideq * 2]
lea fact_x3q, [fact_x1q + fact_x_strideq * 2]
.loop:
; load the x interpolation factors
movu m4, [fact_xq + offsetq] ; fact x + 0 -> m4
movu m5, [fact_x1q + offsetq] ; fact x + 1 -> m5
movu m6, [fact_x2q + offsetq] ; fact x + 2 -> m6
movu m7, [fact_x3q + offsetq] ; fact x + 3 -> m7
; load the x indices of the source values
movu m15, [idx_xq + offsetq]
psllq m15, m15, 3
movq idx_x_valq, xm15
movu m8, [srcq + idx_x_valq]
vpermq m13, m15, 1
movq idx_x_valq, xm13
movu m9, [srcq + idx_x_valq]
vpermq m13, m15, 2
movq idx_x_valq, xm13
movu m10, [srcq + idx_x_valq]
vpermq m13, m15, 3
movq idx_x_valq, xm13
movu m11, [srcq + idx_x_valq]
TRANSPOSE4x4 m8, m9, m10, m11, m12, m13
mulpd m14, m8, m4
vfmadd231pd m14, m9, m5
vfmadd231pd m14, m10, m6
vfmadd231pd m14, m11, m7
mulpd m14, m0
movq xm13, src_strideq
vbroadcastsd m13, xm13
paddq m15, m13
movq idx_x_valq, xm15
movu m8, [srcq + idx_x_valq]
vpermq m13, m15, 1
movq idx_x_valq, xm13
movu m9, [srcq + idx_x_valq]
vpermq m13, m15, 2
movq idx_x_valq, xm13
movu m10, [srcq + idx_x_valq]
vpermq m13, m15, 3
movq idx_x_valq, xm13
movu m11, [srcq + idx_x_valq]
TRANSPOSE4x4 m8, m9, m10, m11, m12, m13
mulpd m13, m8, m4
vfmadd231pd m13, m9, m5
vfmadd231pd m13, m10, m6
vfmadd231pd m13, m11, m7
vfmadd231pd m14, m13, m1
movq xm13, src_strideq
vbroadcastsd m13, xm13
paddq m15, m13
movq idx_x_valq, xm15
movu m8, [srcq + idx_x_valq]
vpermq m13, m15, 1
movq idx_x_valq, xm13
movu m9, [srcq + idx_x_valq]
vpermq m13, m15, 2
movq idx_x_valq, xm13
movu m10, [srcq + idx_x_valq]
vpermq m13, m15, 3
movq idx_x_valq, xm13
movu m11, [srcq + idx_x_valq]
TRANSPOSE4x4 m8, m9, m10, m11, m12, m13
mulpd m13, m8, m4
vfmadd231pd m13, m9, m5
vfmadd231pd m13, m10, m6
vfmadd231pd m13, m11, m7
vfmadd231pd m14, m13, m2
movq xm13, src_strideq
vbroadcastsd m13, xm13
paddq m15, m13
movq idx_x_valq, xm15
movu m8, [srcq + idx_x_valq]
vpermq m13, m15, 1
movq idx_x_valq, xm13
movu m9, [srcq + idx_x_valq]
vpermq m13, m15, 2
movq idx_x_valq, xm13
movu m10, [srcq + idx_x_valq]
vpermq m13, m15, 3
movq idx_x_valq, xm13
movu m11, [srcq + idx_x_valq]
TRANSPOSE4x4 m8, m9, m10, m11, m12, m13
mulpd m13, m8, m4
vfmadd231pd m13, m9, m5
vfmadd231pd m13, m10, m6
vfmadd231pd m13, m11, m7
vfmadd231pd m14, m13, m3
add offsetq, mmsize
jg .store_partial
movu [dstq + offsetq - mmsize], m14
js .loop
jmp .finish
.store_partial:
sub offsetq, ELEM_SIZE
jz .store3
sub offsetq, ELEM_SIZE
jz .store2
.store1:
; offsetq is now mmsize-2 after the write position
movq [dstq + offsetq - mmsize + 2 * ELEM_SIZE], xm14
jmp .finish
.store2:
; offsetq is now mmsize-2 after the write position
movu [dstq + offsetq - mmsize + 2 * ELEM_SIZE], xm14
jmp .finish
.store3:
; offsetq is now mmsize-1 after the write position
movu [dstq + offsetq - mmsize + 1 * ELEM_SIZE], xm14
vextractf128 xm14, m14, 1
movq [dstq + offsetq - mmsize + 3 * ELEM_SIZE], xm14
.finish:
RET
|
