vf_interlace: Add SIMD for lowpass filter

Signed-off-by: Luca Barbato <lu_zero@gentoo.org>

3 files changed, 124 insertions, 0 deletions

diff --git a/libavfilter/x86/Makefile b/libavfilter/x86/Makefile
index 16b1307d31..13b5d318ec 100644
--- a/libavfilter/x86/Makefile
+++ b/libavfilter/x86/Makefile
@@ -1,9 +1,11 @@
 OBJS-$(CONFIG_GRADFUN_FILTER)                += x86/vf_gradfun_init.o
 OBJS-$(CONFIG_HQDN3D_FILTER)                 += x86/vf_hqdn3d_init.o
+OBJS-$(CONFIG_INTERLACE_FILTER)              += x86/vf_interlace_init.o
 OBJS-$(CONFIG_VOLUME_FILTER)                 += x86/af_volume_init.o
 OBJS-$(CONFIG_YADIF_FILTER)                  += x86/vf_yadif_init.o
 
 YASM-OBJS-$(CONFIG_GRADFUN_FILTER)           += x86/vf_gradfun.o
 YASM-OBJS-$(CONFIG_HQDN3D_FILTER)            += x86/vf_hqdn3d.o
+YASM-OBJS-$(CONFIG_INTERLACE_FILTER)         += x86/vf_interlace.o
 YASM-OBJS-$(CONFIG_VOLUME_FILTER)            += x86/af_volume.o
 YASM-OBJS-$(CONFIG_YADIF_FILTER)             += x86/vf_yadif.o
diff --git a/libavfilter/x86/vf_interlace.asm b/libavfilter/x86/vf_interlace.asm
new file mode 100644
index 0000000000..8c2e9b099c
--- /dev/null
+++ b/libavfilter/x86/vf_interlace.asm
@@ -0,0 +1,75 @@
+;*****************************************************************************
+;* x86-optimized functions for interlace filter
+;*
+;* Copyright (C) 2014 Kieran Kunhya <kierank@obe.tv>
+;*
+;* This file is part of Libav.
+;*
+;* Libav is free software; you can redistribute it and/or modify
+;* it under the terms of the GNU General Public License as published by
+;* the Free Software Foundation; either version 2 of the License, or
+;* (at your option) any later version.
+;*
+;* Libav is distributed in the hope that it will be useful,
+;* but WITHOUT ANY WARRANTY; without even the implied warranty of
+;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;* GNU General Public License for more details.
+;*
+;* You should have received a copy of the GNU General Public License along
+;* with Libav; if not, write to the Free Software Foundation, Inc.,
+;* 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
+;******************************************************************************
+
+%include "libavutil/x86/x86util.asm"
+
+SECTION_RODATA
+
+SECTION .text
+
+%macro LOWPASS_LINE 0
+cglobal lowpass_line, 5, 5, 7
+    add r0, r1
+    add r2, r1
+    add r3, r1
+    add r4, r1
+    neg r1
+
+    pxor m6, m6
+
+.loop
+    mova m0, [r2+r1]
+    punpcklbw m1, m0, m6
+    punpckhbw m0, m6
+    paddw m0, m0
+    paddw m1, m1
+
+    mova m2, [r3+r1]
+    punpcklbw m3, m2, m6
+    punpckhbw m2, m6
+
+    mova m4, [r4+r1]
+    punpcklbw m5, m4, m6
+    punpckhbw m4, m6
+
+    paddw m1, m3
+    pavgw m1, m5
+
+    paddw m0, m2
+    pavgw m0, m4
+
+    psrlw m0, 1
+    psrlw m1, 1
+
+    packuswb m1, m0
+    mova [r0+r1], m1
+
+    add r1, mmsize
+    jl .loop
+REP_RET
+%endmacro
+
+INIT_XMM sse2
+LOWPASS_LINE
+
+INIT_XMM avx
+LOWPASS_LINE
diff --git a/libavfilter/x86/vf_interlace_init.c b/libavfilter/x86/vf_interlace_init.c
new file mode 100644
index 0000000000..231ab85a1c
--- /dev/null
+++ b/libavfilter/x86/vf_interlace_init.c
@@ -0,0 +1,47 @@
+/*
+ * Copyright (C) 2014 Kieran Kunhya <kierank@obe.tv>
+ *
+ * This file is part of Libav.
+ *
+  * Libav is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; either version 2 of the License, or
+ * (at your option) any later version.
+ *
+ * Libav is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License along
+ * with Libav; if not, write to the Free Software Foundation, Inc.,
+ * 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
+ */
+
+#include "libavutil/attributes.h"
+#include "libavutil/cpu.h"
+#include "libavutil/internal.h"
+#include "libavutil/mem.h"
+#include "libavutil/x86/asm.h"
+#include "libavutil/x86/cpu.h"
+
+#include "libavfilter/interlace.h"
+
+void ff_lowpass_line_sse2(uint8_t *dstp, ptrdiff_t linesize,
+                          const uint8_t *srcp,
+                          const uint8_t *srcp_above,
+                          const uint8_t *srcp_below);
+void ff_lowpass_line_avx (uint8_t *dstp, ptrdiff_t linesize,
+                          const uint8_t *srcp,
+                          const uint8_t *srcp_above,
+                          const uint8_t *srcp_below);
+
+av_cold void ff_interlace_init_x86(InterlaceContext *s)
+{
+    int cpu_flags = av_get_cpu_flags();
+
+    if (EXTERNAL_SSE2(cpu_flags))
+        s->lowpass_line = ff_lowpass_line_sse2;
+    if (EXTERNAL_AVX(cpu_flags))
+        s->lowpass_line = ff_lowpass_line_avx;
+}