1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
|
(* Copyright 2004 Sascha Husa, Ian Hinder, Christiane Lechner
This file is part of Kranc.
Kranc is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2 of the License, or
(at your option) any later version.
Kranc is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with Kranc; if not, write to the Free Software
Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
*)
BeginPackage["Schedule`", {"Thorn`", "KrancGroups`", "MapLookup`", "Errors`", "Helpers`", "Kranc`"}];
CreateKrancScheduleFile;
Begin["`Private`"];
(* --------------------------------------------------------------------------
Scheduling
-------------------------------------------------------------------------- *)
simpleGroupStruct[groupName_, timelevels_, maxtimelevels_] :=
{
Group -> groupName,
Timelevels -> timelevels,
MaxTimelevels -> "other_timelevels"
};
evolvedGroupStruct[groupName_, timelevels_, maxtimelevels_] :=
{
Group -> groupName,
Timelevels -> timelevels,
MaxTimelevels -> "timelevels"
};
rhsGroupStruct[groupName_, timelevels_, maxtimelevels_] :=
{
Group -> groupName,
Timelevels -> timelevels,
MaxTimelevels -> "rhs_timelevels"
};
groupsSetInCalc[calc_, groups_] :=
Module[{gfs, eqs, lhss, gfsInLHS, lhsGroupNames},
gfs = allGroupVariables[groups];
eqs = lookup[calc, Equations];
lhss = Map[First, eqs];
gfsInLHS = Union[Cases[lhss, _ ? (MemberQ[gfs,#] &), Infinity]];
lhsGroupNames = containingGroups[gfsInLHS, groups];
Return[lhsGroupNames]
];
(* Each calculation can be scheduled at multiple points, so this
function returns a LIST of schedule structures for each calculation
*)
scheduleCalc[calc_, groups_] :=
Module[{points, conditional, conditionals, keywordConditional,
keywordConditionals, triggered, keyword, value, keywordvaluepairs,
groupsToSync, groupName, userSchedule, groupSched, fnSched,
selbcSched, appbcSched, bcGroupName, condParams, bcGroupSched, before, after, relStr},
conditional = mapContains[calc, ConditionalOnKeyword];
conditionals = mapContains[calc, ConditionalOnKeywords];
triggered = mapContains[calc, TriggerGroups];
If[conditional,
keywordConditional = lookup[calc, ConditionalOnKeyword];
If[! MatchQ[keywordConditional, {lhs_String, rhs_String}],
ThrowError["ConditionalOnKeyword entry in calculation expected to be of the form {parameter, value}, but was ", keywordConditional, "Calculation is ", calc]];
keyword = keywordConditional[[1]];
value = keywordConditional[[2]];
];
If[conditionals,
keywordConditionals = lookup[calc, ConditionalOnKeywords];
If[! MatchQ[keywordConditionals, {{_, _} ...}],
ThrowError["ConditionalOnKeywords entry in calculation expected to be of the form {{parameter, value}}, but was ", keywordConditionals, "Calculation is ", calc]];
keywordvaluepairs =
Map[# /. {keyword_, value_} -> {Parameter -> keyword, Value -> value} &,
keywordConditionals];
];
groupsToSync = If[lookupDefault[calc, Where, Everywhere] === Interior ||
lookupDefault[calc, Where, Everywhere] === Boundary,
groupsSetInCalc[calc, groups],
{}];
before = lookupDefault[calc, Before, None];
after = lookupDefault[calc, After, None];
relStr = If[before =!= None, " before " <> before, ""]
<> If[after =!= None, " after " <> after, ""];
applyBCs = lookupDefault[calc, ApplyBCs, False];
userSchedule = lookupDefault[calc, Schedule, Automatic];
If[userSchedule =!= Automatic && !applyBCs,
Return[Map[
Join[
{
Name -> lookup[calc, Name],
SchedulePoint -> # <> relStr,
SynchronizedGroups -> If[StringMatchQ[#, "*MoL_CalcRHS*", IgnoreCase -> True] || StringMatchQ[#, "*MoL_RHSBoundaries*", IgnoreCase -> True],
{},
groupsToSync],
Language -> CodeGenC`SOURCELANGUAGE,
Comment -> lookup[calc, Name]
},
If[triggered, {TriggerGroups -> lookup[calc, TriggerGroups]},
{}],
If[conditional, {Conditional -> {Parameter -> keyword, Value -> value}},
{}],
If[conditionals, {Conditionals -> keywordvaluepairs},
{}]
] &,
lookup[calc, Schedule]]],
(* Scheduling is automatic. For the moment, all automatically
scheduled functions are going to be performed in
MoL_PseudoEvolution in a new group, along with routines to apply
boundary conditions to the variables set in the calculation. All
variables set in the calculation will be synchronised. *)
groupName = lookup[calc, Name] <> "_group";
bcGroupName = lookup[calc, Name] <> "_bc_group";
condParams = Join[
If[conditional,
{Conditional -> {Parameter -> keyword, Value -> value}}, {}],
If[conditionals, {Conditionals -> keywordvaluepairs}, {}]];
groupSched = {
Name -> "group " <> groupName,
SchedulePoint -> If[applyBCs, First[userSchedule] <> relStr, "in MoL_PseudoEvolution" <> relStr],
SynchronizedGroups -> {},
Language -> "None",
Comment -> lookup[calc, Name]
}
~Join~ condParams;
fnSched = {
Name -> lookup[calc, Name],
SchedulePoint -> "in " <> groupName,
Language -> CodeGenC`SOURCELANGUAGE,
Comment -> lookup[calc, Name]
};
bcGroupSched[where_] := {
Name -> "group " <> bcGroupName,
SchedulePoint -> where,
SynchronizedGroups -> {},
Language -> "None",
Comment -> lookup[calc, Name]
}
~Join~ condParams;
selbcSched = {
Name -> lookup[calc, Name] <> "_SelectBCs",
SchedulePoint -> "in " <> bcGroupName,
SynchronizedGroups -> groupsToSync,
Options -> "level",
Language -> CodeGenC`SOURCELANGUAGE,
Comment -> lookup[calc, Name] <> "_SelectBCs"
};
appbcSched = {
Name -> "group ApplyBCs as " <> lookup[calc,Name] <> "_ApplyBCs",
SchedulePoint -> "in " <> bcGroupName <> " after " <> lookup[calc, Name] <> "_SelectBCs",
Language -> "None",
Comment -> "Apply BCs for groups set in " <> lookup[calc, Name]
};
Return[{groupSched, fnSched} ~Join~ If[groupsToSync =!= {},
{selbcSched, appbcSched,
bcGroupSched["in "<>groupName <> " after " <> lookup[calc, Name]],
bcGroupSched["in MoL_PseudoEvolutionBoundaries after MoL_PostStep"]},{}]]]];
CreateKrancScheduleFile[calcs_, groups_, evolvedGroups_, rhsGroups_, nonevolvedGroups_, thornName_,
evolutionTimelevels_] :=
Module[{scheduledCalcs, scheduledStartup, scheduleMoLRegister, globalStorageGroups, scheduledFunctions, schedule},
scheduledCalcs = Flatten[Map[scheduleCalc[#, groups] &, calcs], 1];
scheduledStartup =
{
Name -> thornName <> "_Startup",
SchedulePoint -> "at STARTUP",
Language -> "C",
Options -> "meta",
Comment -> "create banner"
};
scheduleMoLRegister =
{
Name -> thornName <> "_RegisterVars",
SchedulePoint -> "in MoL_Register",
Language -> "C",
Options -> "meta",
Comment -> "Register Variables for MoL"
};
scheduleRegisterSymmetries =
{
Name -> thornName <> "_RegisterSymmetries",
SchedulePoint -> "in SymmetryRegister",
Language -> "C",
Options -> "meta",
Comment -> "register symmetries"
};
globalStorageGroups =
Join[
Map[Module[{tl},
tl = NonevolvedTimelevels[groupFromName[#, groups]];
If[tl===1,
simpleGroupStruct[#, tl, evolutionTimelevels],
evolvedGroupStruct[#, evolutionTimelevels, evolutionTimelevels]]] &,
nonevolvedGroups],
Map[evolvedGroupStruct[#, evolutionTimelevels, evolutionTimelevels] &,
evolvedGroups],
Map[rhsGroupStruct[#, evolutionTimelevels, evolutionTimelevels] &,
rhsGroups]];
scheduledFunctions =
Join[{scheduledStartup, scheduleMoLRegister, scheduleRegisterSymmetries},
scheduledCalcs, CactusBoundary`GetScheduledFunctions[thornName, evolvedGroups]];
schedule = CreateSchedule[globalStorageGroups,
CactusBoundary`GetScheduledGroups[thornName], scheduledFunctions];
Return[schedule]];
End[];
EndPackage[];
|
